{ config, pkgs, lib, inputs, ... }:
{
  programs.chromium = {
    enable = true;
    package = pkgs.ungoogled-chromium.override { enableWideVine = true; };
    commandLineArgs = [
      "--extension-mime-request-handling=always-prompt-for-install" # Enable Extension-Install Dialogue
      "--enable-features=NoReferrers,SpoofWebGLInfo" # Feature Flags
      "--no-default-browser-check"
    ];
    extensions = let
      createChromiumExtensionFor = browserVersion: { id, sha256, version }: {
        inherit id;
        crxPath = builtins.fetchurl {
          url = "https://clients2.google.com/service/update2/crx?response=redirect&acceptformat=crx2,crx3&prodversion=${browserVersion}&x=id%3D${id}%26installsource%3Dondemand%26uc";
          name = "${id}.crx";
          inherit sha256;
        };
        inherit version;
      };
      createChromiumExtension = createChromiumExtensionFor (lib.versions.major pkgs.ungoogled-chromium.version);
    in [
      { # Chromium Web Store
        id = "ocaahdebbfolfmndjeplogmgcagdmblk";
        crxPath = builtins.fetchurl {
          url = "https://github.com/NeverDecaf/chromium-web-store/releases/download/v1.5.4.3/Chromium.Web.Store.crx";
          name = "ocaahdebbfolfmndjeplogmgcagdmblk.crx";
          sha256 = "sha256:0ck5k4gs5cbwq1wd5i1aka5hwzlnyc4c513sv13vk9s0dlhbz4z5";
        };
        version = "1.5.4.3";
      }
      (createChromiumExtension { # uBlock Origin
        id = "cjpalhdlnbpafiamejdnhcphjbkeiagm";
        sha256 = "sha256-cT7Pj59uyWd0B/BCQqMvqYalDM/KZou1c+XqMC7IG5k=";
        version = "1.65.0";
      })
      (createChromiumExtension { # I still don't care about cookies
        id = "edibdbjcniadpccecjdfdjjppcpchdlm";
        sha256 = "sha256:11k7cxcjafs8ziaxl4bilbfwbgl2yf1p6v1bvwszadcr14xyvgsj";
        version = "1.1.4";
      })
      (createChromiumExtension { # KeePassXC-Browser
        id = "oboonakemofpalcgghocfoadofidjkkk";
        sha256 = "sha256-/WHmIE+tbdm3a1QZSFH5tsf3gqOCT2GrfD8TfrvMC3Q=";
        version = "1.9.9.1";
      })
      (createChromiumExtension { # LanguageTool
        id = "oldceeleldhonbafppcapldpdifcinji";
        sha256 = "sha256-c1rqueEpFqZvgS4TpyeC3HlVNQ06CLjNlaYOKsq0rp0=";
        version = "9.0.1";
      })
      (createChromiumExtension { # dark reader
        id = "eimadpbcbfnmbkopoojfekhnkhdbieeh";
        sha256 = "sha256-8/tzlj4xc1h/+Zeek4r9l0I4/Kw3EJgLaqTTxZbRGcU=";
        version = "4.9.110";
      })
    ];
  };
}